Week 6 Homework - Solutions

Submit your homework as a MS Word or PDF document this week. Solve the 4 problems below. In each case cut and paste the model and results into this document.

1. Problem 1 (7 pts) – use CP in OPL to solve textbook problem 12.9-2. This is very similar to one of the examples in the presentation this week. Paste your model and results here:

using CP;

int x[1..6] = [3,6,9,12,15,18];

dvar int p[1..5] in 1..6;

int c[1..5] = [5,8,10,15,20];

maximize sum(k in 1..5) ( c[k]\*x[p[k]] - x[p[k]]^2 );

subject to {

ct1:

allDifferent(p);

ct2: // constrain x1 = x[p[1]] to be in {3,6,12}

p[1]==1 || p[1]==2 || p[1]==4;

ct3: // constrain x2 = x[p[2]] to be in {3,6}

p[2]==1 || p[2]==2;

ct4: // constrain x3 = x[p[3]] to be in {3,6,9,12}

p[3]<=4;

ct5: // constrain x4 = x[p[4]] to be in {6,12}

p[4]==2 || p[4]==4;

ct6: // constrain x5 = x[p[5]] to be in {9,12,15,18}

p[5]>=3;

    ct7: // x1 + x3 + x4 <= 25

    x[p[1]] + x[p[3]] + x[p[4]] <= 25;

}

execute{

writeln('x1 is ',x[p[1]]);

writeln('x2 is ',x[p[2]]);

writeln('x3 is ',x[p[3]]);

writeln('x4 is ',x[p[4]]);

writeln('x5 is ',x[p[5]]);

}

// solution with objective 138

x1 is 3

x2 is 6

x3 is 9

x4 is 12

x5 is 15

1. Problem 2 (8 pts) – use CP in OPL to solve textbook problem 12.9-5. You’ll need to create a “dummy” race as a place to assign the fifth swimmer. Paste your model and results here:

using CP;

range R = 1..5;

// times[i][j] is the time that swimmer i swims for race j

float times[R][R] = [ [ 37.7, 43.4, 33.3, 29.2, 0],

[ 32.9, 33.1, 28.5, 26.4, 0],

[ 33.8, 42.2, 38.9, 29.6, 0],

[ 37.0, 34.7, 30.4, 28.5, 0],

[ 35.4, 41.8, 33.5, 31.1, 0]];

string race[R] = ["Backstroke","Breaststroke","Butterfly","Freestyle","Nothing"];

string swimmer[R] = ["Carl","Chris","David","Tony","Ken"];

dvar int assign[R] in R;

minimize sum(k in R) times[assign[k]][k];

subject to {

ct1:

allDifferent(assign);

}

execute{

for (var r in R) {

writeln( swimmer[assign[r]],' swims ',race[r],' with time ',times[assign[r]][r]);

}

}

// solution with objective 126.2

David swims Backstroke with time 33.8

Tony swims Breaststroke with time 34.7

Chris swims Butterfly with time 28.5

Carl swims Freestyle with time 29.2

Ken swims Nothing with time 0

1. Problem 3 (7 pts) – solve the Traveling Salesman Problem using CP as discussed in the presentation and in problem 12-9.8. Write a CP program in OPL to solve the TSP introduced on page 621 of your book. You can start with the file tsp\_cp\_skeleton.mod in the download packet. The model file includes the cost matrix associated with the graph in figure 14.4. Note that we are using a very large value of $M$ as the cost between cities which are not connected to prevent the solution from using those connections. Paste your model and results here:

using CP;

int n = 7;

int M = 1000;

int c[1..n][1..n] =

[ [ 0, 12, 10, M, M, M, 12],

[12, 0, 8, 12, M, M, M],

[10, 8, 0, 11, 3, M, 9],

[ M, 12, 11, 0, 11, 10, M],

[ M, M, 3, 11, 0, 6, 7],

[ M, M, M, 10, 6, 0, 9],

[12, M, 9, M, 7, 9, 0]];

range R = 2..n;

dvar int x[R] in R;

minimize c[1,x[2]] + c[x[n],1] + sum(j in 2..(n-1)) c[x[j],x[j+1]];

subject to {

allDifferent(x);

}

Solution: visit cities in order 1-3-5-7-6-4-2-1. This is the opposite of the order of the optimal solution in the book and is equivalent

1. Problem 4 (8 pts) – use CP in OPL to solve the Reliable Construction Company construction scheduling problem described in the supplemental textbook section 22.1 (in download packet). You’ll want to study the example sched\_intro.mod that is included with OPL (File -> New -> Example …) which is also in the download packet for convenience (we deleted some stuff in the version in the download packet for simplicity). Paste your model and results here:

// Solve Scheduling Problem for Reliable Construction Company

// From Hillier Chapter 22

using CP;

dvar interval excavate size 2;

dvar interval foundation size 4;

dvar interval roughWall size 10;

dvar interval roof size 6;

dvar interval extPlumb size 4;

dvar interval intPlumb size 5;

dvar interval extSiding size 7;

dvar interval extPaint size 9;

dvar interval electric size 7;

dvar interval wallboard size 8;

dvar interval flooring size 4;

dvar interval intPaint size 5;

dvar interval extFixture size 2;

dvar interval intFixture size 6;

minimize endOf(intFixture); // assumes intFixture last

subject to {

endBeforeStart(excavate, foundation);

endBeforeStart(foundation, roughWall);

endBeforeStart(roughWall, roof);

endBeforeStart(roughWall, extPlumb);

endBeforeStart(extPlumb, intPlumb);

endBeforeStart(roof, extSiding);

endBeforeStart(extPlumb, extPaint);

endBeforeStart(extSiding, extPaint);

endBeforeStart(roughWall, electric);

endBeforeStart(intPlumb, wallboard);

endBeforeStart(electric, wallboard);

endBeforeStart(wallboard, flooring);

endBeforeStart(wallboard, intPaint);

endBeforeStart(extPaint, extFixture);

endBeforeStart(flooring, intFixture);

endBeforeStart(intPaint, intFixture);

}

execute {

writeln("Excavate: " + excavate.start + ".." + excavate.end);

writeln("Lay Foundation: " + foundation.start + ".." + foundation.end);

writeln("Rough Wall: " + roughWall.start + ".." + roughWall.end);

writeln("Roof: " + roof.start + ".." + roof.end);

writeln("Exterior Plumbing: " + extPlumb.start + ".." + extPlumb.end );

writeln("Interior Plumbing: " + intPlumb.start + ".." + intPlumb.end);

writeln("Exterior Siding: " + extSiding.start + ".." + extSiding.end);

writeln("Exterior Painting: " + extPaint.start + ".." + extPaint.end);

writeln("Electrical Work: ", electric.start + ".." + electric.end);

writeln("Install Wallboard: " + wallboard.start + ".." + wallboard.end);

writeln("Install Flooring: " + flooring.start + ".." + flooring.end);

writeln("Interior Painting: " + intPaint.start + ".." + intPaint.end);

writeln("Exterior Fixtures: " + extFixture.start + ".." + extFixture.end);

writeln("Interior Fixtures: " + intFixture.start + ".." + intFixture.end);

}

// solution

Excavate: 0..2

Lay Foundation: 2..6

Rough Wall: 6..16

Roof: 16..22

Exterior Plumbing: 16..20

Interior Plumbing: 20..25

Exterior Siding: 22..29

Exterior Painting: 29..38

Electrical Work: 16..23

Install Wallboard: 25..33

Install Flooring: 33..37

Interior Painting: 33..38

Exterior Fixtures: 38..40

Interior Fixtures: 38..44